pro netcdf_edr_to_binary, infile,edrtype, outfile
; William Johnston
; Computational Physics Inc
; For Naval Research Laboratory, Remote Sensing Division (Windsat) Code 7223
;
;  INFILE is a .edr.nc file
;  edrtype is one of 'edrLowRes' 'edrMidRes' or 'edrHiRes'
;
;  The output is a flat binary edr file

if n_elements(outfile) eq 0 then outfile=strmid(infile,0,strpos(infile,'.edr.nc'))+'.'+edrtype

case edrtype of
  'edrLowRes': res = 0
  'edrMidRes': res = 1
  'edrHiRes' : res = 2
  else: begin
    print, edrtype + ' is not a valid type'
    return
  end
endcase

netcdf_reader, infile,infile+'.dat'
restore,infile+'.dat'

edrp_rec = {edrp, jd:0.0d0, lat:0.0, lon:0.0, scan_angle:0.0, EIA:0.0,  $
		CAA:0.0, scan_num:0L, dcnum:0, surface:0, SDR_QC_flag:0L,  $
		SDR_rec_num:0L, sstErr:0B, wspdErr: 0B, vaporErr: 0B, cloudErr: 0B, $
		sst:0.0, vapor:0.0, cloud:0.0,  $
		num_ambig:0, selected:0, wspd:fltarr(4), wind_dir:fltarr(4),  $
		chisquare:fltarr(4), model_wspd:0.0, model_wdir:0.0,  $
		EDR_QC_flag1:0L, selectedNN:0B, land2water:0B, EDR_QC_flag2:0, $
		rain_rate:0.0, phiErr: bytarr(4) }

n=n_elements(jd)
edr=replicate(edrp_rec,n)
edr.jd = jd
edr.lat = lat
edr.lon = lon
edr.scan_angle = scanangle
edr.eia = eia
edr.caa = caa
edr.scan_num = scan_num
edr.dcnum = dc_num
edr.surface = surface
edr.sdr_qc_flag = reform(sdr_qc_flags[*,res])
;edr.sdr_rec_num = 
edr.ssterr = reform(sst_err[*,res])
edr.wspderr = reform(wspd_err[*,res])
edr.vaporerr = reform(vapor_err[*,res])
edr.clouderr = reform(cloud_err[*,res])
edr.sst = reform(sst[*,res])
edr.vapor = reform(vapor[*,res])
edr.cloud = reform(cloud[*,res])
edr.num_ambig = reform(num_ambiguities[*,res])
edr.selected = reform(selected_nudged[*,res])
edr.wspd = reform(wind_speed[*,*,res])
edr.wind_dir = reform(wind_dir[*,*,res])
edr.chisquare = reform(chi_squared_prob[*,*,res])
edr.model_wspd = reform(model_wind_speed[*,res])
edr.model_wdir = reform(model_wind_dir[*,res])
edr.edr_qc_flag1 = reform(edr_qc_flags1[*,res])
edr.selectedNN = reform(selected_unnudged[*,res])
edr.land2water = reform(land2water[*,res])
edr.edr_qc_flag2 = reform(edr_qc_flags2[*,res])
edr.rain_rate = rain_rate
edr.phierr = reform(wind_dir_err[*,*,res])

openw,lun,outfile,/get_lun
writeu,lun,edr
close,lun
free_lun,lun

end